Aminet 19/Aminet 19 (1997)(GTI - Schatztruhe)[!][Jun 1997].iso/Aminet/comm/fido/AFManager.lha/AFM/AFManager.source

Text File | 1997-03-02 | 22KB | 738 lines

/*
 * AREAFIX MANAGER © 1993 PSR Software, based on AreaFixMan v3.0
 * $VER: AFManager 1.4 (01.03.96)
 *
 * PROGRAM DESRIPTION
 *
 *   Makes area fixing much simpler, for Spot users only.
 *
 * AUTHOR(S)
 *
 *   Original AFM v3.0 by Paul Ruane of PSR Software.
 *
 *        2:252/149.3  @fidonet
 *        2:253/516.12 @fidonet
 *        39:135/14.3  @amiganet
 *        39:135/13.12 @amiganet
 *
 *   All modifications from AFM 3.0 by Sylvain Bourcier, Daddy B@@ze...
 *
 *        1:167/151.66 @fidonet
 *
 * DISCLAIMER
 *
 *   Freeware. Should not have been altered or modified without permission,
 *   but... This version has not been approved for release by PSR.
 *
 * PROGRAM HISTORY
 *
 *  v1.4 -Added %QUERY to options requester.
 *       -Slightly better areaname checks, but you can still screw up.
 *       -Erase action will prompt instead of erasing last entry.
 *       -No longer accepts same attach/detach action more than once.
 *       -Added manual detach, to detach from areas that have a very low
 *        mailflow and from which you might not yet have received anything.
 *
 *  v1.3 -Removed signature in AFM-Written messages, some areafix programs
 *        choke on it - and on tearlines, very lame.
 *
 *  v1.2 -Added check to remove leading +/- from area names.
 *       -Added check to remove leading % when entering special option.
 *       -Added request to proceed IF Length(areaname)>30.
 *       -Fixed deleterequest in openprefs - quotes, always one missing ;)
 *       -Special %options and pswd options asked in same requester now.
 *       -No longer writes a message if no attach/detach and no option.
 *
 *  v1.1 -Didn't Upper the right variable in PROCESSAREAFILE. Fixed.
 *
 *  v1.0 -Improved area selection, can be started from anywhere!
 *       -Prefs requesters will contain value of last prefs entry.
 *       -If prefs file is invalid, you don't have to quit and restart.
 *       -Add areas from message now works!
 *       -Add areas from an external file!
 *       -Announce asked at time of detach.
 *       -Some more crap removed, fixed or improved.
 */

/*---------------------------------------------------------------------------
                  You may edit the following to your likes
---------------------------------------------------------------------------*/

DETACH_SUBJECT="So Long and thanks for all the fish..."
DETACH_FILE="Rexx:Spot/AFM/AFManager.announce"
PREF_FILE="Areafixman.prefs"
EDITOR="Rexx:StartCed.rexx"
CHAR="~"
CHARNAME="Tilde"
CURRENTFORMAT="FORMAT 2.6"
MAXACTION=20

/*---------------------------------------------------------------------------
                                   SETUP
---------------------------------------------------------------------------*/

FILE="ENV:"||PREF_FILE
FILESAVE="ENVARC:"||PREF_FILE
TEMP="T:Spot.AFManager.temp"
TEMP2="T:Spot.AFManager.temp2"
LF="0d"x
Tmp=0
Fromnumber=0
Fromarea="NONE"
message=""
helpmsg.=""
helpitems=3
helpmsg.1="Messages to AreaFix should be in your MATRIX/NETMAIL areas."||LF
helpmsg.1=helpmsg.1||"If you send it in any other area, other people may see your"||LF
helpmsg.1=helpmsg.1||"password and assume your identity."
helpmsg.2="If you started AFM from a message, selecting MESSAGE will"||LF
helpmsg.2=helpmsg.2||"bring up an editor with it's content.  You can then put the"||LF
helpmsg.2=helpmsg.2||"character '"||CHARNAME||"' in front of areanames you wish to attach."||LF
helpmsg.2=helpmsg.2||"The FILE option will do the same with a file of your choice."||LF||LF
helpmsg.2=helpmsg.2||"¹AFM will retrieve only ONE area name per line."||LF
helpmsg.2=helpmsg.2||"²Remember, you must use the REALNAMES for Areafix to work."
helpmsg.3="AFM can send a predefined message in the area"||LF
helpmsg.3=helpmsg.3||"you are detaching from. The current message is:"||LF
helpmsg.3=helpmsg.3||DETACH_FILE

If ~show('ports','SPOT') Then Do
  Say '+++ Error! You must be in SPOT to use this script.'
  Exit 10
End

Address SPOT
OPTIONS RESULTS
SIGNAL ON BREAK_C
SIGNAL ON SYNTAX
SIGNAL ON NOVALUE
SIGNAL ON FAILURE

'isiconified'
If RC=0 Then 'uniconify'

/* Verify if prefs file exists and create one if not */

Tmp=verifyprefsfile()
  If Tmp>9 Then Exit 10  /*fatal error*/
  If Tmp>0 Then Exit     /*user aborted*/
  Call Close('PREFS')

/*---------------------------------------------------------------------------
                              GET NETMAIL AREA
---------------------------------------------------------------------------*/

'ismessages'
If RC=0 Then Do
 'getnummsgs'
  If RESULT>0 Then Do
   'getmessagenum'
    Fromnumber=RESULT
   'getareaname'
    Fromarea=RESULT
  End
End

'isarealist'
If ~(RC=0) Then 'arealist'
Do Forever
 'requestarea' 'TITLE "Areafix to which area?"'
  If RC>0 Then Exit
 'gotoarea' RESULT
  If RC=0 Then Leave
End

'getareaname'
REAL_NAME=RESULT

If ~(left(REAL_NAME,3)='NET') Then Do Forever
 'gotomatrixarea'
  If RC=0 Then Do
   'getareaname'
    MATRIXNAME=RESULT
    MATRIXNAME2='_NET('substr(RESULT,5)')'
   'gotoarea' REAL_NAME /*go back to original area*/
   'requestresponse PROMPT "'REAL_NAME' is not a NETMAIL area!'LF'Do you really wish to Areafix to a public echo?" GADGETS "'MATRIXNAME2'|_Continue|_Help|_QUIT" CENTER'
    If RC=0 Then Exit
    If RC=1 Then Do
      REAL_NAME=MATRIXNAME
     'gotoarea' MATRIXNAME
      Leave
      End
    If RC=2 Then Leave
    If RC=3 Then Call help(1)
    End
  Else Do
   'requestresponse PROMPT "'REAL_NAME' is not a NETMAIL area!'LF'Do you really wish to Areafix to a public echo?" GADGETS "_Continue|_Help|_QUIT" CENTER'
    If RC=0 Then Exit
    If RC=1 Then Leave
    If RC=2 Then Call help(1)
    End
End

/*---------------------------------------------------------------------------
                                 READ PREFS
---------------------------------------------------------------------------*/

/* Now we try to open the prefs file again... */

Tmp=verifyprefsfile()
  If Tmp>9 Then Exit 10  /*fatal error*/
  If Tmp>0 Then Exit     /*user aborted*/

/* File should be opened past the first line */

DEFAULTBOSS='1:167/151'
DEFAULTPASS='yourpassword'

Do Until EOF('PREFS')

  DUMMY='dummy'
  AREA=Strip(ReadLn('PREFS'),'L')
  ADDRESS=Strip(ReadLn('PREFS'),'L')
  PASS=Strip(ReadLn('PREFS'),'L')
  AREAFIX=Strip(ReadLn('PREFS'),'L')

  If Length(PASS)>0 Then DEFAULTPASS=PASS
  If Length(ADDRESS)>0 Then DEFAULTBOSS=ADDRESS

  COMMENT=Strip(ReadLn('PREFS'),'L')
  If Length(COMMENT)=0 Then Do
    COMMENT='Options'
    End
  Else Do
    ANNOUNCE=Strip(ReadLn('PREFS'),'L') /*no longer necessary but left for compatibility*/
    If Length(ANNOUNCE)=0 Then Do
      ANNOUNCE='No Announce'
      DUMMY=''
      End
    Else Do /* Any new prefs will be inserted here */
      Do until Length(DUMMY)=0
        DUMMY=ReadLn('PREFS')
      End
    End
  End

  If AREA=REAL_NAME Then Do /*we found the area*/
    Call Close('PREFS')
    Signal DOAREAFIX
  End

End

/*---------------------------------------------------------------------------
                             ADD AREA TO PREFS
---------------------------------------------------------------------------*/

Call Close('PREFS')

'requeststring TITLE "Boss" PROMPT "Enter the address of your boss'LF'for the area 'REAL_NAME'." DEFAULT 'DEFAULTBOSS' CENTER'
 If RC>0 Then Exit
 ADDRESS=RESULT

'requeststring TITLE "Password" PROMPT "Enter your password for this boss." DEFAULT 'DEFAULTPASS' CENTER'
 If RC>0 Then Exit
 PASS=RESULT

'requeststring TITLE "AreaFix" PROMPT "Enter name of the Areafix handler'LF'for this boss or leave unaltered." DEFAULT "Areafix" CENTER'
 If RC>0 Then Exit
 AREAFIX=RESULT

'requeststring TITLE "Comment" PROMPT "Enter optional comment/reminder for this area." CENTER'
 If RC>0 Then Exit
 COMMENT=RESULT
 If Length(COMMENT)=0 Then COMMENT="Options"

 ANNOUNCE='AnnounceDummy'

 /* 'requestresponse' 'TITLE "Announce" PROMPT "Do you want a message sent'LF'to areas you detach from?" GADGETS " _Yes | _No | _QUIT "'
  *  If RC=0 Then Exit
  *  If RC=2 Then ANNOUNCE='No Announce' */

 /* Further prefs will be added here as they are thought of */

'requestresponse PROMPT "You have changed the prefs." GADGETS "_Save|_Use|_QUIT" CENTER'
 If RC=0 Then Exit
 saveit=RC
 If ~Open('PREFS',FILE,'a') Then Do
  'requestnotify PROMPT "FATAL ERROR!'LF'Could not re-open prefs file ('FILE')"'
   Exit 10
 End
 Call WriteLn('PREFS',REAL_NAME)
 Call WriteLn('PREFS',ADDRESS)
 Call WriteLn('PREFS',PASS)
 Call WriteLn('PREFS',AREAFIX)
 Call WriteLn('PREFS',COMMENT)
 Call WriteLn('PREFS',ANNOUNCE)
 Call WriteLn('PREFS','')
 Call Close('PREFS')
 If saveit=1 Then Address COMMAND 'Copy 'FILE FILESAVE

/*---------------------------------------------------------------------------
                               DO AREA FIXING
---------------------------------------------------------------------------*/

DOAREAFIX:

COUNT=0
ENTRY.=''
Address COMMAND
 'Delete >NIL: 'TEMP
 'Delete >NIL: 'TEMP2
Address SPOT

/*---------------------------------------------------------------------------
                             AREAFIX MAIN LOOP
---------------------------------------------------------------------------*/

FIXAREA:

Do Forever

  TEXT=''
  AFMCommand=0
 'arealist'

  If COUNT>0 Then Do c=1 To (COUNT-1)
    If LENGTH(ENTRY.c)>30 Then TEXT2=Left(ENTRY.c,30)'...'
      Else TEXT2=ENTRY.c
    If c<10 Then TEXT=TEXT||'(0'c')   '||TEXT2||LF
      Else TEXT=TEXT||'('c')   '||TEXT2||LF
  End
  If LENGTH(ENTRY.COUNT)>30 Then TEXT2=Left(ENTRY.COUNT,30)'...'
    Else TEXT2=ENTRY.c
  If COUNT<10 Then TEXT=TEXT||'(0'COUNT')   '||TEXT2
    Else TEXT=TEXT||'('COUNT')   '||TEXT2

  If COUNT<MAXACTION Then Do
    If COUNT>0 Then Do
     'requestresponse TITLE "'COMMENT'" PROMPT "'TEXT'" GADGETS "_Attach|_Detach|_Erase Action|_Done|_Quit"'
      AFMCommand=RC
      End
    Else Do
     'requestresponse TITLE "'COMMENT'" PROMPT "(no command)" GADGETS "_Attach|_Detach|_Done|_Quit"'
      AFMCommand=RC
      If AFMCommand=3 Then AFMCommand=4
      End
    End
  Else Do
   'requestresponse TITLE "'COMMENT'" PROMPT "'TEXT'" GADGETS "_Erase Action|_DONE|_QUIT"'
    AFMCommand=RC
    If AFMCommand>0 Then AFMCommand=AFMCommand+2
  End

  /*AFMCommands: 1=attach, 2=detach, 3=erase, 4=done, 0=quit*/

  Select
    When AFMCommand=0 Then Exit
    When AFMCommand=1 Then Call attachareas()
    When AFMCommand=2 Then Call detachareas()
    When AFMCommand=4 Then Call wearedone()
    When AFMCommand=3 Then Call eraseaction()
  End

End
Exit

/*---------------------------------------------------------------------------
                                 PROCEDURES
---------------------------------------------------------------------------*/

      /*-----------------------------------------------------------
                                 OPEN PREFS
      -----------------------------------------------------------*/

/* Verify that prefs file is alive and valid. CAREFUL, RECURSIVE!
 * If RESULT=0 file stays opened and 1st line has been read.
 * If RESULT=10 there is NO OPENED FILE! You should Exit.
 */

verifyprefsfile: PROCEDURE EXPOSE FILE FILESAVE PREFS CURRENTFORMAT LF

If ~Open('PREFS',FILE,'r') Then Do
  If ~Open('PREFS',FILE,'w') Then Do
   'requestnotify TITLE "Error" PROMPT "FATAL ERROR!'LF'Could not create prefs file ('FILE')"'
    Return '10'
  End
  Call WriteLn('PREFS','FORMAT 2.6')
  Call Close('PREFS')
 'requestnotify PROMPT "A new prefs file has been created."'
  If ~Open('PREFS',FILE,'r') Then Do
   'requestnotify TITLE "Error" PROMPT "FATAL ERROR!'LF'Could not re-open prefs file ('FILE')"'
    Return '10'
  End
End

FORMAT=ReadLn('PREFS')
If ~(FORMAT=CURRENTFORMAT) Then Do
  message = 'PREFS file is not compatible with this version of AFM.'||LF
  message = message||'Delete the prefs files and create a new one?'
 'requestresponse TITLE "Delete?" PROMPT "'message'" GADGETS "_Delete|_QUIT" CENTER'
  If RC=1 Then Do
    Call Close('PREFS')
    Address COMMAND
      'Delete' ">NIL:" FILE
      'Delete' ">NIL:" FILESAVE
    Address SPOT
    LocalResult=verifyprefsfile() /* Deleted file, let's create a new one */
    Return LocalResult
  End
  Return '5'
End
Return '0'

      /*-----------------------------------------------------------
                                ATTACH AREAS
      -----------------------------------------------------------*/

attachareas:

Do Forever

 'requestresponse TITLE "Attach Method" PROMPT "You may select areas in one of 3 ways" GADGETS "M_anually|_Message|_File|_Help|_Cancel" CENTER'
  If RC=0 Then Return
  ATTACHCommand=RC

  If ATTACHCommand=4 Then Call help(2)

  If ATTACHCommand=1 Then Do
    Do Forever
     'requeststring TITLE "Manual attach" PROMPT "Enter area name to attach,'LF'Cancel to End." CENTER'
      If RC>0 Then Leave
      AREANAM=RESULT
      Tmp=checkareaname()
      If Tmp>0 Then Leave
      Dup=0
      Do c=1 To COUNT
        If ENTRY.c='+'AREANAM Then Dup=1
      End
      If Dup=0 Then Do
        COUNT=COUNT+1
        ENTRY.COUNT='+'||AREANAM
      End
      If COUNT=MAXACTION Then Return
    End
    Return
  End

  If ATTACHCommand=2 Then Do
    If Fromnumber=0 Then 'requestnotify PROMPT "You did not Call AFM from a message."'
    Else Do
     'gotoarea' Fromarea
      If RC>0 Then Do
       'requestnotify TITLE "Error" PROMPT "Unable to reach message#'Fromnumber' in area 'Fromarea'."'
        Return
      End
     'messages'
     'gotomessage' Fromnumber
      If RC>0 Then Do
       'requestnotify TITLE "Error" PROMPT "Unable to reach message#'Fromnumber' in area 'Fromarea'."'
        Return
      End
     'saveascii TO "'TEMP2'" OVERWRITE NOHEADER NOTEARLINE NOORIGIN NOKLUDGES NOREFLOW'
      If RC>0 Then Do
       'requestnotify TITLE "Error" PROMPT "Unable to save message to 'TEMP2'"'
        Return
      End
      Call processareafile()
      Return
    End
  End

  If ATTACHCommand=3 Then Do
   'requestfile TITLE "Select textfile"'
    If RC=0 Then Do
      Address COMMAND 'Copy 'RESULT TEMP2
      If RC>0 Then Do
       'requestnotify TITLE "Error" PROMPT "Unable to copy file to 'TEMP2'"'
        Return
      End
      Call processareafile()
      Return
    End
  End

End
Return

      /*-----------------------------------------------------------
                             PROCESS AREA FILE
      -----------------------------------------------------------*/

processareafile:

'WB2Front'
 Address COMMAND '"'EDITOR'"' '"'TEMP2'"'
'Spot2Front'
 If Open('ATTACHFILE',TEMP2,'r') Then Do
   Do While ~EOF('ATTACHFILE') & (COUNT<MAXACTION)
     ALINE=ReadLn('ATTACHFILE')
     P=Pos(CHAR,ALINE)
     If P>0 Then Do
       ALINE=Right(ALINE,Length(ALINE)-P)
       AREANAM=Word(ALINE,1)
       Tmp=checkareaname()
       If Tmp=0 Then Do
         Dup=0
         Do c=1 To COUNT
           If ENTRY.c='+'AREANAM Then Dup=1
         End
         If Dup=0 Then Do
           COUNT=COUNT+1
           ENTRY.COUNT='+'||AREANAM
         End
       End
     End
   End
   Call Close('ATTACHFILE')
 End
 Else 'requestnotify TITLE "Error" PROMPT "Unable to ReOpen file 'TEMP2'"'

Return

      /*-----------------------------------------------------------
                                DETACH AREAS
      -----------------------------------------------------------*/

detachareas:

'requestresponse TITLE "Detach Method" PROMPT "You may select areas in one of 2 ways" GADGETS "_AreaList|_Manually|_Cancel" CENTER'
 If RC=0 Then Return
 DETACHCommand=RC

 If DETACHCommand=1 Then Do
   Do Forever
    'requestarea TITLE "Select area to detach" ALL'
     If RC>0 Then Return
    'gotoarea' RESULT
    'getareaname'
     AREANAM=RESULT
     If (left(AREANAM,3)='NET') Then Do
      'requestresponse TITLE "Hmmmm..." PROMPT "Are you sure you want'LF'to detach a NETMAIL area?" GADGETS "_No!|_Yes" CENTER'
       If RC=0 Then Leave
     End
     Else Leave
   End
   Dup=0
   Do c=1 To COUNT
     If ENTRY.c='-'AREANAM Then Dup=1
   End
   If Dup=0 Then Do Forever
    'requestresponse TITLE "Announce" PROMPT "Announce your departure?" GADGETS "_Yes|_No|_Help|_Cancel" CENTER'
     If RC=0 Then Leave
     If RC=3 Then Call help(3)
     Else Do
       ANNOUNCE=RC
       COUNT=COUNT+1
       ENTRY.COUNT='-'||Upper(AREANAM)
       If ANNOUNCE=1 Then Do
         If Exists(DETACH_FILE) Then Do
          'gotoarea' AREANAM
          'messages'
          'write TO "ALL" SUBJECT "'DETACH_SUBJECT'" ORIGIN "AFManager v1.1" FILE "'DETACH_FILE'"'
           If RC>0 Then 'requestnotify TITLE "Error" PROMPT "Unable to write farewell message."'
         End
         Else 'requestnotify TITLE "Error" PROMPT "Unable to open announce file:'LF||DETACH_FILE'."'
       End
       Leave
     End
   End
   Return
 End

If DETACHCommand=2 Then Do
  Do Forever
   'requeststring TITLE "Manual detach" PROMPT "Enter area name to detach,'LF'Cancel to End." CENTER'
    If RC>0 Then Leave
    AREANAM=RESULT
    Tmp=checkareaname()
    If Tmp>0 Then Leave
    Dup=0
    Do c=1 To COUNT
      If ENTRY.c='-'AREANAM Then Dup=1
    End
    If Dup=0 Then Do
      COUNT=COUNT+1
      ENTRY.COUNT='-'||AREANAM
      If COUNT=MAXACTION Then Return
    End
  End
  Return
End

Return

      /*-----------------------------------------------------------
                              CHECK AREANAME
      -----------------------------------------------------------*/

checkareaname: PROCEDURE EXPOSE AREANAM LF

/* Remove unusual/invalid chars, like quotes or at@ signs */
   BADCHAR=' @^,;:="'||"'"||"`"
   AREANAM=Compress(AREANAM,BADCHAR)

/* Remove leading +/- action character if user entered one by himself */
   AREANAM=Strip(Strip(AREANAM,'L','+'),'L','-')

/* Remove leading/trailing "." from UUCP names and UPPER */
   AREANAM=Upper(Strip(AREANAM,'B','.'))

   If Length(AREANAM)=0 Then Return '1'
   If Length(AREANAM)>30 Then Do
     message = 'LongName: '||Left(AREANAM,30)||'...'||LF||LF
     message = message||'Some systems limit the length of Areanames'||LF
     message = message||'to 30 chars or so. Proceed with operation?'
    'requestresponse TITLE "LongName" PROMPT "'message'" GADGETS "_Proceed|_Cancel" CENTER'
     If RC=0 Then Return '1'
     End

Return '0'

      /*-----------------------------------------------------------
                               ERASE ACTION
      -----------------------------------------------------------*/

eraseaction:

Do Forever

  TEXT='Enter action number to erase:'||LF||LF

  If COUNT>0 Then Do c=1 To (COUNT-1)
    If LENGTH(ENTRY.c)>30 Then TEXT2=Left(ENTRY.c,30)'...'
      Else TEXT2=ENTRY.c
    If c<10 Then TEXT=TEXT||'   (0'c')   '||TEXT2||LF
      Else TEXT=TEXT||'   ('c')   '||TEXT2||LF
  End
  If LENGTH(ENTRY.COUNT)>30 Then TEXT2=Left(ENTRY.COUNT,30)'...'
    Else TEXT2=ENTRY.COUNT
  If COUNT<10 Then TEXT=TEXT||'   (0'COUNT')   '||TEXT2
    Else TEXT=TEXT||'   ('COUNT')   '||TEXT2

 'requestnumber TITLE "Erase action" PROMPT "'TEXT'"'
  If RC>0 Then Return

  AREANUM=RESULT
  IF AREANUM=0 Then Return

  If AREANUM<COUNT Then Do c=AREANUM To COUNT
    d=c+1
    ENTRY.c=ENTRY.d
  End
  If AREANUM<=COUNT Then COUNT=COUNT-1
  If COUNT=0 Then Return

End

Return

      /*-----------------------------------------------------------
                                WE ARE DONE
      -----------------------------------------------------------*/

wearedone:

TEMPPASS=PASS
If ~Open('AFMMESSAGE',TEMP,'w') Then Do
 'requestnotify TITLE "Error" PROMPT "FATAL ERROR!'LF'Could not open temporary file ('TEMP')"'
  Exit 10
End

If COUNT>0 Then Do c=1 TO COUNT
  Call WriteLn('AFMMESSAGE',ENTRY.c)
  End

 Option=0
'requestresponse TITLE "Special options" PROMPT "Send a special option to Areafix?" GADGETS "_No|%%_LIST|%%_HELP|%%_QUERY|%%_Other|_Password"'
 SpecialOption=RC
 Select
   When SpecialOption=2 Then Do
     Call WriteLn('AFMMESSAGE','%LIST')
     Option=1
     End
   When SpecialOption=3 Then Do
     Call WriteLn('AFMMESSAGE','%HELP')
     Option=1
     End
   When SpecialOption=4 Then Do
     Call WriteLn('AFMMESSAGE','%QUERY')
     Option=1
     End
   When SpecialOption=5 Then Do
    'requeststring TITLE "Other options" PROMPT "Enter the special command you wish to send" CENTER'
     If RC=0 Then Do
       Tmp=Strip(RESULT,'L','%')
       Tmp=Word(Tmp,1)
       Tmp="%"Upper(Tmp)
       If Length(Tmp)>1 Then Do
         Call WriteLn('AFMMESSAGE',Tmp)
         Option=1
         End
       End
     End
   When SpecialOption=0 Then Do
    'requeststring TITLE "Password options" PROMPT "Add options to the password'Lf'eg. -L -H" DEFAULT "'PASS'" CENTER'
     If RC=0 Then Do
       Tmp=RESULT
       If (Length(Tmp)>0)&(Length(Tmp)>Length(PASS)) Then Do
         PASS=Tmp
         Option=1
         End
       End
     End
   Otherwise NOP
 End

If (COUNT>0)|(Option=1) Then Do /* do we have something to ask areafix? */

/*Call WriteLn('AFMMESSAGE','')                   */
/*Call WriteLn('AFMMESSAGE',"--- AFManager v1.4") */

  Call Close('AFMMESSAGE')
 'gotoarea' REAL_NAME
 'messages'
 'write TO "'AREAFIX'" TOADDR "'ADDRESS'" SUBJECT "'PASS'" FILE "'TEMP'" REFLOW=OFF NOSIG NOEDIT NOGUI'
  If RC>0 Then Do
   'requestnotify PROMPT "FATAL ERROR!'LF'Could not write message to areafix!"'
    Exit 10
    End
 'lastmessage'
  End
Else Call Close('AFMMESSAGE')

Address COMMAND
 'Delete >NIL: 'TEMP
 'Delete >NIL: 'TEMP2

Exit

      /*-----------------------------------------------------------
                                    HELP
      -----------------------------------------------------------*/

help:
ARG helpindex
If helpindex<(helpitems+1) Then 'requestnotify TITLE "Help" PROMPT "'helpmsg.helpindex'"'
Else Do
  say '+++ Error! Unavailable help for index 'helpindex
  Exit 10
End
Return

      /*-----------------------------------------------------------
                               ERROR HANDLERS
      -----------------------------------------------------------*/

BREAK_C:
say "+++ Break!"
Exit 10
SYNTAX:
say "+++ Syntax Error ("RC") at line "SIGL" : "errortext(RC)
Exit 10
NOVALUE:
say "+++ No Value Error at line "SIGL
Exit 10
FAILURE:
Say "+++ Failure! Something's fishy at line "SIGL
Exit 10